// ==========================================================================
//                                plt_pov.pov
// ==========================================================================
//
// This file is a template for running POV-Ray on the output of plt_pov.
// plt_pov outputs a file containing a molecular object called "onomol" 
// which is referenced by this file. Down below you will see an include line
// where you should enter the name of your ono plot file. 
// The default is "all.pov".
// Then on gere you can run povray on this file, for example with the command :
//
// % povray -i plt_pov.pov -o plt_pov.tga +a +q9 +w300 +h300
//
// and then look at the resulting targa file with xv, photoshop or gimp :
//
// % xv plt_pov.tga
//
// You can convert the file to other formats with xv, photoshop, gimp, imconv
// 
// % imconv plt_pov.tga plt_pov.tiff
//
// If you're not happy with the result, you can try changing the parameters
// in this file. Good luck. The user manual for POV-Ray is 300 pages long.
//
//                                                  MRH 27-May-99/19-Oct-99
//
// ==========================================================================

// Include standard POV-Ray version 3.1 definitions

#include "/home/markh/povray/colors.inc"
#include "/home/markh/povray/textures.inc"
#include "/home/markh/povray/finish.inc"
#include "/home/markh/povray/shapes.inc"

// Define our own rendering options for various structures

#declare Plastic_Alwyn = finish {specular 0.5 roughness 0.04 ambient .3 diffuse .6}
#declare Plastic_Lines = finish {specular 0.5 roughness 0.04 ambient .3 diffuse .6}
#declare Plastic_Ribbons = finish {specular 0.2 roughness 0.08 ambient .5 diffuse .3}
#declare Plastic_Maps = finish {specular 0.5 roughness 0.04 ambient .3 diffuse .6}
#declare Plastic_Balls = finish {specular 0.5 roughness 0.04 ambient .3 diffuse .6}
#declare Plastic_Sticks = finish {specular 0.3 roughness 0.04 ambient .3 diffuse .6}

#declare Metallic_Alwyn = finish {specular 0.8 roughness 0.01 ambient .25 diffuse .5 metallic brilliance 4 reflection 0.5}
#declare Metallic_Lines = finish  {specular 0.8 roughness 0.01 ambient .25 diffuse .5 metallic brilliance 4 reflection 0.5}
#declare Metallic_Ribbons = finish  {specular 0.8 roughness 0.01 ambient .25 diffuse .5 metallic brilliance 4 reflection 0.5}
#declare Metallic_Maps = finish  {specular 0.8 roughness 0.01 ambient .25 diffuse .5 metallic brilliance 4 reflection 0.5}
#declare Metallic_Balls = finish  {specular 0.8 roughness 0.01 ambient .25 diffuse .5 metallic brilliance 4 reflection 0.5}
#declare Metallic_Sticks = finish  {specular 0.8 roughness 0.01 ambient .25 diffuse .5 metallic brilliance 4 reflection 0.5}

#declare Map_Trans = 0.5;
#declare Ball_Trans = 0.0;
#declare Stick_Trans = 0.0;
#declare Ribbon_Trans = 0.0;
#declare Other_Trans = 0.0;

#declare Trans_Map = 0.5;
#declare Trans_Ball = 0.0;
#declare Trans_Stick = 0.0;
#declare Trans_Ribbon = 0.0;
#declare Trans_Other = 0.0;

#declare Line_Width = 0.02;
#declare Text_Scale = 1.0;
#declare Hb_Dot_Size = 0.08;
#declare Ttf_File = "/home/markh/povray/povray31/include/arial.ttf"
#declare Ttf_File = "/home/markh/povray/povray31/include/timrom.ttf"

// =================================================================
// Here we include the file from plt_pov containing molecule onomol 
// =================================================================

#include "all.pov"
 
// =================================================================

// The following you may want to change :
// ====================================

// Stereo should be set to yes for stereo, no for mono.
// Frame_Scale_Mono scales the entire mono image.
// Frame_Scale_Stereo scales each stereo view.
// Camera_Distance determines field-of-view.
// Stereo_Cross should be set to yes for cross-eyed, no for wall-eyed.
// Background is background colour.

#declare Stereo = no;

#declare Sep_Stereo = 10.0;
#declare Frame_Scale_Stereo = 3;
#declare Frame_Scale_Mono = 7;

#declare Camera_Distance = 165.0;

#declare Stereo_Cross = yes;

background {rgb <1.0, 1.0, 1.0>}

// Set up Stereo parameters
// ========================

#if (Stereo = yes) 
	#declare Stereo_Sep = Sep_Stereo;
	#declare Frame_Scale = Frame_Scale_Stereo;
#else
	#declare Stereo_Sep = 0.0;
	#declare Frame_Scale = Frame_Scale_Mono;
#end

#if (Stereo_Cross = no) 
	#declare Stereo_Angle = 2.0;
#else
	#declare Stereo_Angle = -2.0;
#end

// Set up lighting (position of lights and colour)
// ===============================================

light_source { <-35, 30, 150> color red 1 green 1 blue 1 }
light_source { < 35, 30, 150> color red .5 green .5 blue .5 }

// Set up camera
// =============

camera { location <    0.0,    0.0,   Camera_Distance>
direction <0, 0, 1.0>
look_at   <0, 0, 0> up y/Frame_Scale right x/Frame_Scale
orthographic
}

// Create the main object
// ======================

object { onomol

#if (Stereo_Sep)
  rotate y*Stereo_Angle
#end	

translate x*Stereo_Sep
}

// Create second camera and object if Stereo_Sep is non-zero
// =========================================================

#if (Stereo_Sep) 
camera { location <    0.0,    0.0,   Camera_Distance>
direction <0, 0, 1.0>
look_at   <0, 0, 0> up y/Frame_Scale right x/Frame_Scale
orthographic
}
 
object { onomol
rotate y*-Stereo_Angle
translate x*-Stereo_Sep
}
#end

// That's it
//==========